Results 1 to 20 of 20

Thread: One heater working, other stays off

  1. #1
    Regular Vistor
    Join Date
    Oct 2016
    Location
    New york
    Posts
    47

    New heater help programming

    Hi first I just got my apex and have no idea what the heck I am doing. I have read the getting started documents etc.

    I have 2 heaters I was looking to setup and rotate them something like this
    DO I NEED 2 PROBE?

    heater 1 to run from 8am to 8 pm
    heater 2 to run from 8 pm to 8am

    wanted t have to have the heater stay in the 78-79 range or unless someone else tell me better?

    Is there a database where programming is stored that I ca review?

    I also have other i hve some questions on lights, pumps, alarms etc .,,, Was looking fora guide I can follow.

  2. #2
    Frequent Contributor zombie's Avatar
    Join Date
    Dec 2013
    Location
    Denver, CO
    Posts
    13,176
    Heater1
    (Temp settings)
    If Time 20:00 to 07:59 Then OFF

    Heater2
    (Temp settings)
    If Time 08:00 to 19:59 Then OFF

    You might be an engineer if...You have no life and can prove it mathematically.

  3. #3
    Regular Vistor
    Join Date
    Oct 2016
    Location
    New york
    Posts
    47
    thanks zombie but will the heaters work together incase one fails? a I thought I saw a program for haters to wait a certain time so heaters don't keep checking over and over.

  4. #4
    Frequent Contributor zombie's Avatar
    Join Date
    Dec 2013
    Location
    Denver, CO
    Posts
    13,176
    If you want both to run of temp is low, add another temp line lower than your hysteresis that turns both on after the if time line.

    You might be an engineer if...You have no life and can prove it mathematically.

  5. #5
    Frequent Visitor
    Join Date
    Jan 2016
    Location
    Cincinnati, ohio
    Posts
    709
    Download the comprehensive reference manual in the Neptune links above. Explains most of the commands, provides proper syntax and gives you programming suggestions

  6. #6
    Frequent Contributor zombie's Avatar
    Join Date
    Dec 2013
    Location
    Denver, CO
    Posts
    13,176
    Quote Originally Posted by PUPU233 View Post
    Has the problem been solved
    I actually answered that in post 4. For example say you want temp between 78.0 and 78.5. I also included some extra failsafes I normally use personally on a 2+ heater setup.

    Heater1
    Fallback ON
    If Temp < 78.1 Then ON
    If Temp > 78.4 Then OFF
    If Time 20:00 to 07:59 Then OFF
    If Temp < 77.9 Then ON

    Heater2
    Fallback OFF
    If Temp < 78.1 Then ON
    If Temp > 78.4 Then OFF
    If Time 08:00 to 19:59 Then OFF
    If Temp < 77.9 Then ON
    If Temp < 75.0 Then OFF

    You might be an engineer if...You have no life and can prove it mathematically.

  7. #7
    Frequent Visitor rkpetersen's Avatar
    Join Date
    Jun 2017
    Location
    Near Seattle
    Posts
    940
    Here's what I use. I have two heaters that alternate the main duty, at 12 hours intervals. If one of them can't quite get to the set point in a timely fashion (say, at night in winter), after a while the other will turn on to help. I use the season tables to set my tank temperature; I've adjusted them so it's only a 1.2 degree F difference between summer and winter. There's a max temp safeguard and I also force the heaters to reset if both remain active together for over 45 minutes. This program activates each heater's EB832 relay about 15 time a day for my particular setup, and allows a daily temp variation of no more than 0.5 degrees F (typically less). I also have a third backup heater that should rarely activate unless something is wrong with one of the other two.

    [Heater1]
    Fallback ON
    If Temp < RT+0.0 Then ON
    Defer 001:15 Then ON
    If Temp > RT+0.1 Then OFF
    If Time 16:00 to 03:59 Then OFF
    If Temp < RT+-0.1 Then ON
    If Output Heater2On030 = ON Then ON
    If Output HeatersOn045 = ON Then OFF
    If Temp > 78.7 Then OFF
    If Output ReturnPump = OFF Then OFF
    If Output LeakDetected = ON Then OFF

    [Heater2]
    Fallback ON
    If Temp < RT+0.0 Then ON
    Defer 001:20 Then ON
    If Temp > RT+0.1 Then OFF
    If Time 04:00 to 15:59 Then OFF
    If Temp < RT+-0.1 Then ON
    If Output Heater1On030 = ON Then ON
    If Output HeatersOn045 = ON Then OFF
    If Temp > 78.7 Then OFF
    If Output ReturnPump = OFF Then OFF
    If Output LeakDetected = ON Then OFF

    [BackupHeater]
    Fallback OFF
    Set OFF
    If Temp < RT+-0.2 Then ON
    Defer 000:30 Then ON
    If Output ReturnPump = OFF Then OFF
    If Output LeakDetected = ON Then OFF

    [Heater1On030]
    Set OFF
    If Output Heater1 = ON Then ON
    Defer 030:00 Then ON

    [Heater2On030]
    Set OFF
    If Output Heater2 = ON Then ON
    Defer 030:00 Then ON

    [HeatersOn045]
    Set OFF
    If Output Heater1 = ON Then ON
    If Output Heater2 = OFF Then OFF
    Defer 045:00 Then ON

  8. #8
    Frequent Visitor rlbannon's Avatar
    Join Date
    Jan 2015
    Location
    Oklahoma
    Posts
    75
    Quote Originally Posted by zombie View Post

    Heater2
    Fallback OFF
    If Temp < 78.1 Then ON
    If Temp > 78.4 Then OFF
    If Time 08:00 to 19:59 Then OFF
    If Temp < 77.9 Then ON
    If Temp < 75.0 Then OFF
    Hi Zombie, Why the last line?

  9. #9
    Master Control Freak RussM's Avatar
    Join Date
    Dec 2012
    Location
    California - US Pacific
    Posts
    22,463
    It is a safety shutoff in case the probe is accidentally removed from water or fails, or if the heater fails and the water temp continues to drop (powers off the heater if it is not working)
    Please do not send me PMs with technical questions or requesting assistance - use the forums for Apex help. PM me ONLY if the matter is of a private or personal nature. Thanks.

  10. #10
    Frequent Visitor rlbannon's Avatar
    Join Date
    Jan 2015
    Location
    Oklahoma
    Posts
    75
    Quote Originally Posted by RussM View Post
    It is a safety shutoff in case the probe is accidentally removed from water or fails, or if the heater fails and the water temp continues to drop (powers off the heater if it is not working)
    Wouldn't this also prevent a functioning heater from coming on again after a total power failure if the temp dropped below 75.0?

  11. #11
    Frequent Contributor zombie's Avatar
    Join Date
    Dec 2013
    Location
    Denver, CO
    Posts
    13,176
    Quote Originally Posted by rlbannon View Post
    Wouldn't this also prevent a functioning heater from coming on again after a total power failure if the temp dropped below 75.0?
    That's part of the reason why that line was only included in heater 2 and not in heater 1.

    You might be an engineer if...You have no life and can prove it mathematically.

  12. #12
    Master Control Freak RussM's Avatar
    Join Date
    Dec 2012
    Location
    California - US Pacific
    Posts
    22,463
    Quote Originally Posted by JurisHP View Post
    //Error: line 2 - Valid keywords following If are Temp, pH, ORP, DO, Cond, Salt, Par, Feed, SwX, FLx, Error, Power, Sun, or Moon // If Temp < RT+0.0 Then ON
    You must use the actual name of the temperature probe, which may not be 'Temp'; it could be 'Tmp' or a custom name you have given it.
    Please do not send me PMs with technical questions or requesting assistance - use the forums for Apex help. PM me ONLY if the matter is of a private or personal nature. Thanks.

  13. #13
    Reef Tank Addict
    Join Date
    Sep 2014
    Location
    Philadelphia, PA
    Posts
    47
    Duh...dumb question. One more thing:

    This line: If Output HeatersOn045 = ON Then OFF is not taking.

    Can I just have 2 lines with the names of my heaters:

    If Output Sys_Heater_A = ON Then OFF
    If Output Sys_Heater_B = ON Then OFF


    Jeff

  14. #14
    Reef Tank Addict
    Join Date
    Sep 2014
    Location
    Philadelphia, PA
    Posts
    47
    So this is what I have now:
    Fallback ON
    If Sys_Tp < RT+0.0 Then ON
    Defer 001:15 Then ON
    If Sys_Tp > RT+0.1 Then OFF
    If Time 16:00 to 03:59 Then OFF
    If Sys_Tp < RT+-0.1 Then ON
    If Output Sys_Heater_B = ON Then ON
    If Output Sys_Heater_A = ON Then OFF
    If Output Sys_Heater_B = ON Then OFF
    If Sys_Tp > 78.7 Then OFF
    If Output Pump_Main = OFF Then OFF
    If Output Alert_Leak = ON Then OFF

    My tank temp at the moment is 75.8, but both heaters are OFF (I have them set to AUTO).

    Why are they not ON?

    Jeff

  15. #15
    Reef Tank Addict
    Join Date
    Sep 2014
    Location
    Philadelphia, PA
    Posts
    47
    I understand where to enter the above programming codes, but where do these go?

    [Heater1On030]
    Set OFF
    If Output Heater1 = ON Then ON
    Defer 030:00 Then ON

    [Heater2On030]
    Set OFF
    If Output Heater2 = ON Then ON
    Defer 030:00 Then ON

    [HeatersOn045]
    Set OFF
    Min Time 015:00 Then OFF
    If Output Heater1 = ON Then ON
    If Output Heater2 = OFF Then OFF
    Defer 045:00 Then ON

    Beneath the first set of coding?

    Jeff

  16. #16
    Frequent Contributor zombie's Avatar
    Join Date
    Dec 2013
    Location
    Denver, CO
    Posts
    13,176
    Is the just the first heating cycle, or has it happened multiple times in a row?

    If the latter, post the code.

    Sent from my SM-G965U using Tapatalk

  17. #17
    NSI Member
    Join Date
    Jan 2013
    Location
    MN
    Posts
    2,552
    Is the B outlet off, or just the heater which is plugged into it? If just the heater and it has its own thermostat, that could be set lower.

    Otherwise as zombie suggested, post the code for the two outlets.

  18. #18
    Reef Tank Addict
    Join Date
    Sep 2014
    Location
    Philadelphia, PA
    Posts
    47
    I actually changed my programs as follows:

    This is my new program for my 2 heaters:


    Heater 1:


    Fallback ON
    If Sys_Tp < RT+0.0 Then ON
    Defer 001:15 Then ON
    If Sys_Tp > RT+0.1 Then OFF
    If Time 16:00 to 03:59 Then OFF
    If Sys_Tp < RT+-0.1 Then ON
    If Output Sys_Heater_B = ON Then ON
    If Output Sys_Heater_A = ON Then OFF
    If Output Sys_Heater_B = ON Then OFF
    If Sys_Tp > 78.7 Then OFF
    If Output Pump_Main = OFF Then OFF
    If Output Alert_Leak = ON Then OFF


    Heater 2:


    Fallback ON
    If Sys_Tp < RT+0.0 Then ON
    Defer 001:20 Then ON
    If Sys_Tp > RT+0.1 Then OFF
    If Time 04:00 to 15:59 Then OFF
    If Sys_Tp < RT+-0.1 Then ON
    If Output Sys_Heater_A = ON Then ON
    If Output Sys_Heater_A = ON Then OFF
    If Output Sys_Heater_B = ON Then OFF
    If Sys_Tp > 78.7 Then OFF
    If Sys_Tp < 70.1 Then OFF
    If Output Pump_Main = OFF Then OFF
    If Output Alert_Leak = ON Then OFF



    My tank is reading 76.8 as the temp---why is the heater not turning ON? I have it set to AUTO.


    Thanks.

    Jeff

  19. #19
    NSI Member
    Join Date
    Jan 2013
    Location
    MN
    Posts
    2,552
    If Output Sys_Heater_B = ON Then ON
    If Output Sys_Heater_A = ON Then OFF
    If Output Sys_Heater_B = ON Then OFF

    Are these the names of the heater Outlets? If so, You have both of them set to shut off if either of them are on. Remove all 3 of these lines if those are the heater outlet names.

    This looks like a mod of my 2 heater program. I think what you are trying to do with those lines is the alert when both heaters are running. If so, those lines go into a virtual outlet not the heater outlet. Like this.

    [Heat-Err]
    Set OFF
    If Output Heat1 = ON Then ON
    If Output Heat2 = OFF Then OFF
    Defer 030:00 Then ON

    this will turn on if both heaters run together longer than 30 minutes. You use the status of the virtual outlet in your alarm statement so you are alerted if the heaters are not keeping up.

  20. #20
    Reef Tank Addict
    Join Date
    Sep 2014
    Location
    Philadelphia, PA
    Posts
    47
    I realized that the codes were in conflict and made the appropriate changes.

    Thank you for your input.

    Jeff

Similar Threads

  1. Moved Heater - Now not working
    By Charlie in forum Misc Apex Usage & Programming
    Replies: 2
    Last Post: 01-23-2018, 11:52
  2. Heater stays off after electrical outage
    By Mps026 in forum Apex Programming for Heaters and Chillers
    Replies: 18
    Last Post: 02-26-2017, 18:49
  3. Chiller and Heater not working on auto
    By SquareFace in forum EnergyBars 832 / 632 / 8 / 6 / 4
    Replies: 9
    Last Post: 12-09-2015, 19:52
  4. Help Heater and feed mode not working
    By Fishpalace in forum Apex Programming for Heaters and Chillers
    Replies: 23
    Last Post: 10-27-2015, 08:01
  5. EB6 staying on ......heater stays on too!
    By Marc2004 in forum EnergyBars 832 / 632 / 8 / 6 / 4
    Replies: 11
    Last Post: 05-19-2015, 08:14

Bookmarks

Bookmarks

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •