In case anyone is curious or wants to try with the Apex Classic, I did finally get this working.
3 Ramps used
Feedmode
start 30
end 30
time 1 minute
Max flow
start 30
end 100
time 5 minutes
Min flow
start 100
end 30
time 5 minutes
3 oscillate commands
Direction toggle switches every 60 minutes leading to an overall timing cycle of 120 minutes. It could be increased to a tidal flow simulation on a 360 minute cycle and the delay oscillation and min/max flow ramps could be adjusted to allow for that.
ToggleDir
Set OFF
OSC 000:00/060:00/060:00 Then OFF
1st delay is ON for 5 minutes, then Off for 55 minutes, then ON for 60 minutes for a total of 120 minutes. As long as the overall cycle matches the direction cycle this should be stable. You would probably want the 5 minute portion to match the min/max ramp times.
delay1
Set ON
OSC 005:00/055:00/060:00 Then OFF
2nd delay stays ON for 65 minutes, then OFF for 55 minutes for a total cycle of 120 minutes. As long as the overall cycle matches the direction toggle, this should be stable. You'll need to do some math here, but the 5 minute portion should match whatever you use for the min/max ramp time.
delay2
Set ON
OSC 065:00/055:00/000:00 Then OFF
This is just a way for a low power night mode where both tunze pumps will end up running at 30%. This lasts from 9pm to 6am
Night
Fallback OFF
Set OFF
If Time 21:00 to 06:00 Then ON
The Left Tunze starts out the cycle when Nightmode shuts off. It will ramp from 30% to 100% over 5 minutes and then ramp down to 30% over 5 minutes and then shut OFF. After an hour it starts at 30% and ramps up to 100% over 5 minutes. When the direction changes it will go from 100% to 30% and then shut off after five minutes. When night mode comes on this Tunze is off, so it just snaps to 30% as these can't run less than 30% reliably. Feedswitch will set output to 30%, but nightmode will override it. There is a maintenance and shutdown switch. These override any other setting and set the tunze to OFF.
Left Tunze
Fallback OFF
If Output ToggleDir = ON Then MaxFlow
If Output ToggleDir = OFF Then MinFlow
If Output Delay1 = OFF Then OFF
If Output FeedSwitch = ON Then FeedMode
If Output Night = ON Then FeedMode
If Time 05:55 to 06:00 Then MaxFlow
If Output MaintSwitch = ON Then OFF
If Output Shutdown = ON Then OFF
Right Tunze will ramp up from 30% to 100% and then when the direction changes will ramp down from 100% to 30% and then after 5 minutes to OFF. When night mode kicks in this unit is running at 100% and will ramp down to 30% over 5 minutes. Feedswitch will set to 30%, but nightmode will override it. There is a maintenance and shutdown switch. These override any other setting and set the tunze to OFF.
Right Tunze
Fallback OFF
If Output ToggleDir = OFF Then MaxFlow
If Output ToggleDir = ON Then MinFlow
If Output Delay2 = OFF Then OFF
If Output FeedSwitch = ON Then FeedMode
If Output Night = ON Then MinFlow
If Output MaintSwitch = ON Then OFF
If Output Shutdown = ON Then OFF
There are likely many other ways to do this, but this works even if it is a bit more complicated than it probably should be.
Bookmarks