Making 2 AFS units cycle "randomly"

[Diznaster]

I have 2 AFS units dispensing different types of food each. Both foods are things everybody eats, just different for variety of diet. My fish have figured out the schedule and tend to get aggressive while around the feeder shortly before feeding time. They know which feeder goes first, then some of them go to the second. I'm trying to figure out the simplest way to alternate which feeder goes first and also shift the times, so it isn't so predictable. To reduce bullying and give the shy fish a better chance of winning the lottery.

I'm thinking I probably need to create two vFeed outlets (one for starting with left feeder and the other with right feeder). Then create 7 VO's (called "Feed M-Su) with a time schedule for each day. Each of these schedule outlets would be split up on the 2 vFeeds (4/3). Then take my four existing StartFeed/StopFeed and double them, this is where I would adjust the defers to make them cycle different. Assign one of the two vFeeds to each set of 4 Start/Stops. Is there a more compact way, am I on the right track?

Current Setup (works fine for controlling drum rotation count and starting one feeder first):

vfeed
Set OFF
If Time 20:00 to 20:05 Then ON
If FeedA 000 Then ON
If Output We-Fed_Defer = ON Then OFF

Feeder_R (AFS Unit)
Fallback OFF
OSC 000:00/000:30/000:30 Then ON
If Output StartFeed_R = OFF Then OFF
If Output StopFeed_R = ON Then OFF

Feeder_L (AFS Unit)
Fallback OFF
OSC 000:00/000:30/000:30 Then ON
If Output StartFeed_L = OFF Then OFF
If Output StopFeed_L = ON Then OFF

StartFeed_R (controls delay from start of vFeed)
Set OFF
If Output vfeed = ON Then ON
Defer 001:00 Then ON

StopFeed_R (controls number of drum rotations)
Set OFF
If Output vfeed = ON Then ON
Defer 002:29 Then ON

StartFeed_L (controls delay from start of vFeed)
Set OFF
If Output vfeed = ON Then ON
Defer 002:00 Then ON

StopFeed_L (controls number of drum rotations)
Set OFF
If Output vfeed = ON Then ON
Defer 002:29 Then ON

We-Fed_Defer (just skips scheduled feeding if recently done by pushing FeedA)
Set OFF
If FeedA 000 Then ON
Defer 004:58 Then ON
Defer 180:00 Then OFF

[zombie]

I woud do this

vFeed1
OSC 000:00/006:00/120:00 Then ON
If Time 21:00 to 18:59 Then OFF
Min Time 006:00 Then ON

vFeed2
OSC 000:00/006:00/060:00 Then ON
If Time 20:00 to 18:59 Then OFF
Min Time 006:00 Then ON


Replace right feeders vFeed line with vFeed1 and replace left with vFeed2

This will randomize them to some degree so they will be offset from each other by a somewhat random amount that constantly changes.

Sent from my SM-G965U using Tapatalk

[Diznaster]

Can you elaborate a bit on what the different OSC are doing? I get what the command does, just not understanding the general concept with the different OFF times.

[zombie]

One will run for 6 minutes every 126 minutes within the available time window and the other will run 6 minutes every 66 minutes. Then the periods are not neat intervals they will end up occurring at different points within those time windows and they will be spread apart by varying amounts. For example on one day vFeed1 will be active at 8:06 PM while the other is active at 7:48 PM. The next day vFeed1 will be active at 9:18 PM while the other is active at 7:06 PM. Every now and then a feed will be skipped. The fish will never be able to gather a pattern with this kind of variation.

Sent from my SM-G965U using Tapatalk

[Diznaster]

OK I get that part thanks.

A couple more follow ups.

1: You said to replace the right feeders vFeed line with vFeed1 and left with vFeed2. I'm assuming you meant replace the Right Start/Stop feeds with vFeed1 (the actual feeders don't have a vFeed line).
2: If I wanted to add 2 feeding times per day (lunch and dinner). I'm thinking I would need to break out the "If Time 21:00 to 18:59 Then OFF" into a separate outlet called "Dinner". Make a similar outlet "If Time 15:00 to 12:59 Then OFF" called "Lunch". Then make each vFeed :

vFeed1
OSC 000:00/006:00/120:00 Then ON
If Lunch OFF then OFF
If Dinner OFF then OFF
Min Time 006:00 Then ON

vFeed2
OSC 000:00/006:00/060:00 Then ON

If Lunch OFF then OFF
If Dinner OFF then OFF

Min Time 006:00 Then ON

With "Lunch" as?:
Set ON

If Time 15:00 to 12:59 Then OFF

[zombie]

OK I get that part thanks.

A couple more follow ups.

1: You said to replace the right feeders vFeed line with vFeed1 and left with vFeed2. I'm assuming you meant replace the Right Start/Stop feeds with vFeed1 (the actual feeders don't have a vFeed line).
2: If I wanted to add 2 feeding times per day (lunch and dinner). I'm thinking I would need to break out the "If Time 21:00 to 18:59 Then OFF" into a separate outlet called "Dinner". Make a similar outlet "If Time 15:00 to 12:59 Then OFF" called "Lunch". Then make each vFeed :

vFeed1
OSC 000:00/006:00/120:00 Then ON
If Lunch OFF then OFF
If Dinner OFF then OFF
Min Time 006:00 Then ON

vFeed2
OSC 000:00/006:00/060:00 Then ON

If Lunch OFF then OFF
If Dinner OFF then OFF

Min Time 006:00 Then ON

With "Lunch" as?:
Set ON

If Time 15:00 to 12:59 Then OFF

If you want to use that approach, you need to make both OSC periods to be approximately the same length but different from each other.

Ex 000:00/006:00/120:00 for one and 000:00/006:00/118:00 for the other for 2 hour windows.

You only need one VO for lunch and dinner

Set OFF
If Time 12:00 to 02:00 Then ON
If Time 19:00 to 20:59 Then ON


Turn the vFeeds off when the VO is active. You can also supress this with your feed delay VO.

Sent from my SM-G965U using Tapatalk

[Diznaster]

With both OSC OFF periods (120:00/118:00) so close would that reduce the "randomness" during each 2 hour window? I really like how scattered they could be in your expanded explanation example.

Also from #1 follow up did you mean to say replace Start/Stop's with the two new vFeeeds (not the actual feeder outlet)?

[zombie]

With both OSC OFF periods (120:00/118:00) so close would that reduce the "randomness" during each 2 hour window? I really like how scattered they could be in your expanded explanation example.

Also from #1 follow up did you mean to say replace Start/Stop's with the two new vFeeeds (not the actual feeder outlet)?

They will be quite random even though the periods are close

Yes. Replace just the vFeed lines.

Sent from my SM-G965U using Tapatalk

[Diznaster]

Thanks, I'll give that a try and report back in a few days of monitoring or sooner if I have problems.

[Diznaster]

I setup the VOs a while back and set them to log. I didn't connect them to the actual feeders, just in case something went wrong and I cycled a feeder way too much. So far everything looks great. Only issues I had was I think there was a typo with:

You only need one VO for lunch and dinner

Set OFF
If Time 12:00 to 02:00 Then ON
If Time 19:00 to 20:59 Then ON

It didn't quite work, but this did:

[Feed_Times]
Set OFF
If Time 20:00 to 12:00 Then ON (On during fasting hours)
If Time 13:59 to 18:01 Then ON (On during break between Lunch and Dinner)
If FeedA 000 Then OFF (It's Feed Time if we hit the A button)
If Output We-Fed_Defer = ON Then ON (We-Fed with the A button, so don't feed on schedule for a period of time)

Today I had what would have been a double feed from one of the feeders because I had "If Time 13:59 to 18:01 Then ON" as "If Time 14:00 to 18:00 Then ON". It was exactly at the start and end of a 2 hour window, so making them a 1:59 window should eliminate that. Not a big deal if they sometimes get an extra feed. I also saw once that one of the feeders missed a 2 hour window, again not a big deal. I'm loving how the times of each feeder is now randomized. I'm ready to attach them to the physical feeders and un-train my fish.

FYI, for anyone else trying to do this

[vFeed1]
OSC 000:00/006:00/120:00 Then ON
If Output Feed_Times = ON Then OFF
Min Time 006:00 Then ON

[vFeed2]

OSC 000:00/006:00/118:00 Then ON
If Output Feed_Times = ON Then OFF
Min Time 006:00 Then ON

Then just substitute vFeed1 for vFeed on the Left Start/Stop and vFeed2 for vFeed on the Right Start/Stop. The Start/Stops just control drum rotation count.